@echo off
setlocal
cd /d "%~dp0"

set "JAVA_HOME=C:\Program Files\Microsoft\jdk-17.0.20.8-hotspot"
set "ANDROID_HOME=%LOCALAPPDATA%\Android\Sdk"
set "ANDROID_SDK_ROOT=%ANDROID_HOME%"
set "PATH=%JAVA_HOME%\bin;%ANDROID_HOME%\cmdline-tools\latest\bin;%ANDROID_HOME%\platform-tools;%PATH%"

if not exist "%ANDROID_HOME%\platforms\android-35" (
  echo Android SDK platform android-35 missing. Run sdkmanager first.
  exit /b 1
)

echo sdk.dir=%ANDROID_HOME:\=\\%> android\local.properties

echo Fetching protocol cores into assets...
powershell -ExecutionPolicy Bypass -File scripts\fetch-android-cores.ps1
if errorlevel 1 exit /b 1

cd android
if not exist gradlew.bat (
  echo Generating Gradle wrapper...
  where gradle >nul 2>&1
  if errorlevel 1 (
    echo Download gradle wrapper via powershell...
    powershell -ExecutionPolicy Bypass -File ..\scripts\bootstrap-gradle.ps1
  ) else (
    gradle wrapper --gradle-version 8.9
  )
)

call gradlew.bat assembleDebug
if errorlevel 1 exit /b 1

cd ..
mkdir dist\navis-release\android 2>nul
copy /Y android\app\build\outputs\apk\debug\app-debug.apk dist\navis-release\android\Navis.apk
echo.
echo APK: dist\navis-release\android\Navis.apk
endlocal